10 X$=SYS(CHR$(7)):R$=LEFT(X$,7):L$=RIGHT(X$,8)
20  REM***************************************************************
30  REM    CMOD1      CMOD1      CMOD1    CMOD1     CMOD1     CMOD1
40  REM ************************************************************
50  REM
60  REM          ENTRY OF UNIVARIATE DATA
70  REM
80  REM ************************************************************
90  DIM #1,A1(111),A2(111),A3(111)
100  OPEN R$ AS FILE 1
140 A1(0)=1
150  PRINT L$
160  PRINT "   ENTRY OF UNIVARIATE DATA - STATISTICAL COMPUTATIONS"
170  PRINT
180  PRINT "THIS MODULE CALCULATES THE MEAN, SUM OF SQUARED"
190  PRINT "DEVIATIONS FROM THE MEAN, AND THE STANDARD DEVIATION"
200  PRINT "OF A SET OF SAMPLE DATA."
210  PRINT
220  PRINT "YOU ARE ASKED TO ENTER YOUR DATA IN GROUPS OF 5"
230  PRINT "OBSERVATIONS.  AFTER YOU HAVE ENTERED A GROUP"
240PRINT"YOU WILL HAVE THE OPPORTUNITY TO REENTER IT."
250  PRINT
260  Q5=0
270  PRINT "HOW MANY OBSERVATIONS ARE THERE IN YOUR SAMPLE?";
280  Q4=0
290  GOSUB 9000
300  Q9=O1
310  IF Q9 <= 0 THEN 330
320  IF (Q9-INT(Q9))=0 THEN 350
330  PRINT "WHAT? TRY AGAIN."
340  GOTO 270
350  PRINT
360  IF Q9<5 THEN 670
370  PRINT "ENTER FIRST GROUP OF OBSERVATIONS."
380  FOR Q1=1 TO (Q9+.5)/5
390  IF Q1=1 THEN 410
400  PRINT "ENTER NEXT GROUP OF OBSERVATIONS."
410  FOR K5=1 TO 5
430A$="##  "
431PRINT USING A$,K5;
440  GOSUB 9000
450  Q(K5)=O1
460  NEXT K5
470  PRINT "HERE IS WHAT YOU ENTERED."
480  PRINT Q(1),Q(2),Q(3),Q(4),Q(5)
490  PRINT "IF YOU WANT TO REENTER THE GROUP TYPE '1'."
500  PRINT "IF YOU NOT TYPE '0'."
510  GOSUB 9000
520  IF O1=0 THEN 580
530  IF O1=1 THEN 560
540  PRINT "REENTER.  INPUT MUST BE 0 OR 1."
550  GOTO 510
560  PRINT "REENTER LAST GROUP OF OBSERVATIONS."
570  GOTO 410
580  Q6=0
590  Q7=0
600  FOR Q2=1 TO 5
610  Q6=Q6+Q(Q2)
620  Q7=Q7+Q(Q2)*Q(Q2)
630  NEXT Q2
640  Q4=Q4+Q6
650  Q5=Q5+Q7
660  NEXT Q1
670  Q3=Q9-5*INT(Q9/5)+.5
680  IF Q3<1 THEN 1060
700A$="ENTER THE LAST ## OBSERVATIONS."
701  PRINT  USING  A$,INT(Q3)
710  FOR K5=1 TO Q3
730A$="#  "
731PRINT USING A$,K5;
740  GOSUB 9000
750  Q(K5)=O1
760  NEXT K5
770  PRINT "HERE IS WHAT YOU ENTERED."
780  V8=INT(Q3)
790  ONV8  GOTO 880,860,840,820,800
800  PRINT Q(1),Q(2),Q(3),Q(4),Q(5)
810  GOTO 890
820  PRINT Q(1),Q(2),Q(3),Q(4)
830  GOTO 890
840  PRINT Q(1),Q(2),Q(3)
850  GOTO 890
860  PRINT Q(1),Q(2)
870  GOTO 890
880  PRINT Q(1)
890  PRINT "IF YOU WANT TO REENTER THE LAST GROUP TYPE '1'."
900  PRINT "IF YOU DON'T TYPE '0'."
910  GOSUB 9000
920  IF O1=1 THEN 960
930  IF O1=0 THEN 980
940  PRINT "REENTER.  INPUT MUST BE 0 OR 1."
950  GOTO 910
960  PRINT "REENTER LAST GROUP."
970  GOTO 710
980  Q7=0
990  Q6=0
1000  FOR Q2=1 TO Q3
1010  Q6=Q6+Q(Q2)
1020  Q7=Q7+Q(Q2)*Q(Q2)
1030  NEXT Q2
1040  Q4=Q4+Q6
1050  Q5=Q5+Q7
1060  Q2=Q5-Q4*Q4/Q9
1070  Q1=Q4/Q9
1080  Q3=SQR(Q2/Q9)
1090  PRINT L$
1100  PRINT
1110  PRINT "               SAMPLE STATISTICS"
1120  PRINT
1140A$="     MEAN                           #########.####"
1141  PRINT  USING  A$ ,Q1
1160A$="     STANDARD DEVIATION             #########.####"
1161  PRINT  USING  A$ ,Q3
1180A$="     VARIANCE                       #########.####"
1181  PRINT  USING  A$ ,Q3^2
1200A$="     SUM OF SQUARED DEVIATIONS      #########.####"
1201  PRINT  USING  A$ ,Q2
1210  PRINT
1220  PRINT "IF YOU WANT TO ENTER ANOTHER DATA SET TYPE '1'."
1230  PRINT "IF YOU DO NOT TYPE '0'."
1240  GOSUB 9000
1250  IF O1=0 THEN 1310
1260  IF O1=1 THEN 1290
1270  PRINT "REENTER.  INPUT MUST BE 0 OR 1."
1280  GOTO 1240
1290  PRINT L$
1300  GOTO 210
1310  CLOSE 1: CHAIN "RSTRT"
9000  REM--SUBROUTINE THAT DETERMINES IF RESTART HAS BEEN REQUESTED.
9005  INPUT O1
9015  IF O1=-9999 THEN 9025
9020  RETURN
9025  CLOSE 1: CHAIN "RSTRT"
9035  REM*************END ROUTINE
9999  END