10X$=SYS(CHR$(7)):R$=LEFT(X$,7):L$=RIGHT(X$,8)
20  REM*******************************************************************
30  REM
40  REM           ENTRY OF BIVARIATE DATA
50  REM
60  REM****************************************************************
70  DIM #1,A1(111),A2(111),A3(111)
80  OPEN R$ AS FILE 1
120A1(0)=22
130  V3=0
140  V8=0
150  DIM C(5),P(5)
160  MAT C=ZER
170  MAT P=ZER
190  PRINT L$
200  PRINT "     ENTRY OF BIVARIATE DATA - STATISTICAL COMPUTATIONS"
210  PRINT
220PRINT"THIS MODULE COMPUTES SAMPLE STATISTICS FOR THE"
230  PRINT "PREDICTOR AND THE CRITERION PLUS CORRELATION AND"
240  PRINT "REGRESSION STATISTICS."
250  PRINT
260  PRINT "YOU ARE ASKED TO INPUT THE DATA IN PAIRS, THE PREDICTOR AND"
270  PRINT "THEN THE CRITERION VALUE. SUPPOSE FOR YOUR FIRST DATA PAIR"
280  PRINT "THE PREDICTOR VALUE IS 4 AND THE CRITERION 6.  THE MESSAGE"
290  PRINT
300  PRINT "INPUT PAIR  1   ?"
310  PRINT
320  PRINT "WILL BE PRINTED.  YOU SHOULD THEN ENTER 4 AND 6 SEPARATED BY"
330  PRINT "A COMMA.  AFTER EACH SET OF 5 PAIRS YOU WILL HAVE THE CHANCE"
340  PRINT "TO REENTER THE SET."
350  PRINT
360  X2=0
370  Y2=0
380  S2=0
390  X1=0
400  Y1=0
410  PRINT "INPUT NUMBER OF DATA PAIRS.";
420  GOSUB 9000
430  N=O1
440  IF N>1 THEN 490
450  PRINT
460  PRINT "REENTER.  NUMBER OF PAIRS MUST BE GREATER THAN 1."
470  PRINT
480  GOTO 410
490  K4=0
500  PRINT L$
510  REM
520  REM
530  REM     INPUT THE DATA PAIRS
540  REM
550  REM
560  FOR K5=1 TO N
570  K8=K5
580A$="INPUT PAIR ####    "
581PRINT USING A$,K5;
600  GOSUB 9050
610  K4=K4+1
620  C(K4)=O2
630  P(K4)=O1
640  IF K4<5 THEN 720
650  GOSUB 880
660  GOSUB 990
670  IF O1=0 THEN 700
680  GOSUB 1070
690  GOTO 650
700  GOSUB 1250
710  K4=0
720  NEXT K5
730  IF K4=0 THEN 1330
740  K5=K8
750  GOSUB 880
760  GOSUB 990
770  IF O1=0 THEN 800
780  GOSUB 1070
790  GOTO 740
800  GOSUB 1250
810  GOTO 1330
820  PRINT "HERE ARE THE LAST 5 PAIRS YOU ENTERED."
830  REM
840  REM
850  REM       ROUTINE TO PRINT INPUT
860  REM
870  REM
880  PRINT
890  PRINT "HERE ARE THE PAIRS YOU ENTERED."
900  FOR K6=1 TO K4
910  PRINT P(K6),C(K6)
920  NEXT K6
930  RETURN
940  REM
950  REM
960  REM   ROUTINE TO ASK IF REENTRY WANTED
970  REM
980  REM
990  PRINT "IF YOU WANT TO REENTER THESE PAIRS TYPE '1' ELSE '0'.";
1010  GOSUB 9000
1020  IF O1=0 THEN 1060
1030  IF O1=1 THEN 1060
1040  PRINT "REENTER.  INPUT MUST BE 0 OR 1."
1050  GOTO 1010
1060  RETURN
1070  REM
1080  REM
1090  REM    ROUTINE TO REENTER
1100  REM
1110  FOR K6=K5-K4+1 TO K5
1130A$="INPUT PAIR #####  "
1131PRINT USING A$,K6;
1140  GOSUB 9050
1150  P(K6-K5+K4)=O1
1160  C(K6-K5+K4)=O2
1170  NEXT K6
1180  RETURN
1190  REM
1200  REM
1210  REM
1220  REM   ROUTINE TO ADD TO COUNTERS
1230  REM
1240  REM
1250  FOR K6=1 TO K4
1260  X1=X1+P(K6)
1270  Y1=Y1+C(K6)
1280  X2=X2+P(K6)^2
1290  Y2=Y2+C(K6)^2
1300  S2=S2+P(K6)*C(K6)
1310  NEXT K6
1320  RETURN
1330  PRINT L$
1340  PRINT "       SAMPLE STATISTICS - BIVARIATE DATA"
1350  PRINT
1360  S1=X1/N
1370  S0=Y1/N
1380  S3=X2-X1*X1/N
1390  S4=Y2-Y1*Y1/N
1400  S5=S2-Y1*X1/N
1410  D1=SQR(S3/N)
1420  D0=SQR(S4/N)
1430  R=S5/(SQR(S3)*SQR(S4))
1440  B=S5/S3
1450  PRINT "                  PREDICTOR         "
1470A$="MEAN                                     ##.#####^^^^"
1471  PRINT  USING  A$ ,S1
1490A$="STANDARD DEVIATION                       ##.#####^^^^"
1491  PRINT  USING  A$ ,D1
1510A$="VARIANCE                                 ##.#####^^^^"
1511  PRINT  USING  A$ ,D1^2
1530A$="SUM OF SQUARED DEVIATIONS                ##.#####^^^^"
1531  PRINT  USING  A$ ,S3
1540  PRINT "                  CRITERION         "
1560A$="MEAN                                     ##.#####^^^^"
1561  PRINT  USING  A$ ,S0
1580A$="STANDARD DEVIATION                       ##.#####^^^^"
1581  PRINT  USING  A$ ,D0
1600A$="VARIANCE                                 ##.#####^^^^"
1601  PRINT  USING  A$ ,D0^2
1620A$="SUM OF SQUARED DEVIATIONS                ##.#####^^^^"
1621  PRINT  USING  A$ ,S4
1630  PRINT "                 CORRELATION        "
1650A$="COEFFICIENT                              ##.###"
1651  PRINT  USING  A$ ,R
1670A$="SQUARE OF COEFFICIENT                    ##.###"
1671  PRINT  USING  A$ ,R^2
1690A$="SUM OF CROSS PRODUCT DEVIATIONS          ##.#####^^^^"
1691  PRINT  USING  A$ ,S5
1700  PRINT "                  REGRESSION"
1720A$="SLOPE                                    ##.#####^^^^"
1721  PRINT  USING  A$ ,B
1740A$="INTERCEPT                                ##.#####^^^^"
1741  PRINT  USING  A$ ,S0+B*(-S1)
1760A$="---------------------------------------------------"
1761PRINT A$
1770  PRINT "IF YOU WANT TO RUN ANOTHER DATA SET TYPE '1'."
1780  PRINT "IF YOU DO NOT TYPE '0'."
1790  GOSUB 9000
1800  IF O1=0 THEN 1850
1810  IF O1=1 THEN 1860
1820  PRINT
1830  PRINT "REENTER.  INPUT MUST BE 0 OR 1."
1840  GOTO 1790
1850  CLOSE 1: CHAIN "RSTRT"
1860  PRINT L$
1870  GOTO 360
9000  REM--SUBROUTINE THAT DETERMINES IF RESTART HAS BEEN REQUESTED.
9005  INPUT O1
9015  IF O1=-9999 THEN 9025
9020  RETURN
9025  CLOSE 1: CHAIN "RSTRT"
9035  REM*************END ROUTINE
9050  REM--SUBROUTINE THAT DETERMINES IF RESTART HAS BEEN REQUESTED.  2 INPUTS
9055  INPUT O1,O2
9065  IF O1=-9999 THEN 9080
9070  IF O2=-9999 THEN 9080
9075  RETURN
9080  CLOSE 1: CHAIN "RSTRT"
9090  REM*************END ROUTINE
9999  END