10  X$=SYS(CHR$(7)):R$=LEFT(X$,7):L$=RIGHT(X$,8)
15  REM *************************************************************
20  REM
25  REM        EXPECTED UTILITY USING NORMAL OGIVE UTILITY FUNCTION
30  REM
35  REM*****************************************************************
40  DIM #1,A1(111),A2(111),A3(111)
45  OPEN R$ AS FILE 1
65 A1(0)=28
70 M1=A3(0):S1=A3(1)
100  X=0
110  PRINT L$
120  PRINT "         EXPECTED UTILITY - NORMAL OGIVE UTILITY FUNCTION"
130  PRINT
140  PRINT "THIS MODULE COMPUTES THE EXPECTED UTILITY WHEN THE UTILITY"
150  PRINT "FUNCTION IS A NORMAL OGIVE FUNCTION AND THE EXPECTATION IS WITH"
160  PRINT "RESPECT TO ANOTHER NORMAL DISTRIBUTION."
170  PRINT
175 IFS1<>0THEN280
176  PRINT
180  PRINT "INPUT THE MEAN OF THE NORMAL OGIVE UTILITY FUNCTION.";
200  GOSUB 9000
210  M1=O1
220  PRINT
225  PRINT "INPUT THE STANDARD DEVIATION.";
230  GOSUB 9000
240  IF O1>0 THEN 270
250  PRINT "REENTER.  STANDARD DEVIATION MUST BE POSITIVE."
260  GOTO 230
270  S1=O1
275 PRINT
278 GOTO 290
280 PRINT "NORMAL OGIVE UTILITY"
282 PRINT
284 PRINT "MEAN =";M1;"  STANDARD DEVIATION =";S1
286PRINT
290  PRINT "INPUT THE MEAN OF THE DISTRIBUTION WITH RESPECT TO WHICH"
295  PRINT "YOU WANT TO TAKE THE EXPECTATION.";
310  GOSUB 9000
320  M2=O1
325  PRINT
330  PRINT "INPUT THE STANDARD DEVIATION OF THE DISTRIBUTION.";
340  GOSUB 9000
350  IF O1>0 THEN 380
360  PRINT "REENTER.  STANDARD DEVIATION MUST BE POSITIVE."
370  GOTO 340
380  S2=O1
390 Y3=(M2-M1)/SQR(S1*S1+S2*S2)
400  GOSUB 8000
405 PRINT L$
410 PRINT "UTILITY FUNCTION     MEAN =";M1
412 PRINT "                   ST DEV =";S1
414 PRINT
416 PRINT "DISTRIBUTION         MEAN =";M2
418 PRINT "                   ST DEV =";S2
420 PRINT
430A$="EXPECTED UTILITY = #.###"
431  PRINT  USING  A$,P
440  PRINT
450  PRINT "TYPE THE NUMBER OF THE OPTION YOU WANT."
460  PRINT "   1. TAKE EXPECTATION WITH RESPECT TO ANOTHER DISTRIBUTION."
465  PRINT "   2. CHANGE THE UTILITY FUNCTION."
470  PRINT "   3. EXIT MODULE"
480  GOSUB 9000
490  IF O1=2 THEN 600
500  IF O1=1 THEN 700
505  IF O1=3 THEN 530
510  PRINT "REENTER.  INPUT MUST BE 1, 2, OR 3."
520  GOTO 480
530  PRINT L$
532  IF I2=1 THEN 560
540  CLOSE 1: CHAIN "RSTRT"
560  PRINT "IF YOU WANT TO FIND THE EXPECTED UTILITY USING THE LEAST"
570  PRINT "SQUARES FIT TYPE '1' ELSE '0'.";
589  GOSUB 9000
590  IF O1=0 THEN 540
591 A3(0)=0
592  CLOSE 1: CHAIN "CMODP"
600  PRINT L$
610  GOTO 176
700  PRINT L$
710  GOTO 280
8000  REM **********************************************************
8001  REM      ROUTINE CALCULATES THE CDF FOR NORMAL DISTRIBUTION
8002  REM               INPUT       Y3
8003  REM               OUTPUT      P
8004  REM
8005  Y4=ABS(Y3)
8010  X1=X
8015  X=Y3
8020  T=1/(1+.231642*Y4)
8021 IF X*X/2<80 THEN 8025
8022 D=0
8023 GOTO 8030
8025  D=.398942*EXP(-X*X/2)
8030  C1=1.33027
8035  C2=1.82126
8040  C3=1.78148
8045  C4=.356564
8050  C5=.319382
8055  P=1-D*T*((((C1*T-C2)*T+C3)*T-C4)*T+C5)
8060  IF X >= 0 THEN 8070
8065  P=1-P
8070  X=X1
8075  RETURN
8076  REM
8077  REM        END OF NORMAL CDF ROUTINE
8078  REM **********************************************************
9000  REM--SUBROUTINE THAT DETERMINES IF RESTART HAS BEEN REQUESTED.
9005  INPUT O1
9015  IF O1=-9999 THEN 9025
9020  RETURN
9025  CLOSE 1: CHAIN "RSTRT"
9035  REM*************END ROUTINE
9999  END