1	!!! PAM12  V04A-3	R. LEAVITT	20-OCT-76	!!!
	!!! PESTICIDE RESEARCH CENTER, MICHIGAN STATE U.	!!!
	!!!
120	E$=SYS(CHR$(6)+CHR$(7))   ! DETACH FROM KEYBOARD
	! PAM12 ACQUIRES DATA FROM THE PDP 8/E AND DISTRIBUTES IT TO
	! THE VARIOUS ACCOUNTS SET UP FOR EACH INSTRUMENT CHANNEL
130	DIM A(300) :
	D$="DK1:" :
	DIM #2%,P1%(0),R1%(200),B(15000)	! P1%(0)=NEXT FREE SPACE IN B
	! R1%(0)=LAST RUN WRITTEN; R1%(1-200)=STARTING POINT IN B FOR EACH RUN
145	ON ERROR GOTO 340 :
	OPEN "KB3:" AS FILE 1%	! FOR PDP-8/E
180	INPUT #1%,A(I%) :
	GOTO 210
200	ON ERROR GOTO 340 :
	INPUT #1%,D :
	IF D<>0 THEN A(I%)=D ELSE
	INPUT #1%,A(I%)	! EACH VALUE SENT BY THE 8/E IS FOLLOWED BY
	! 2 TERMINATORS.  THUS, EVERY OTHER VALUE RECEIVED
	! IS A 0 AND MUST BE ELIMINATED
205	IF I%=1% THEN A(1)=A(1)+(VAL(RIGHT(DATE$(0),8))-70%)*1000%
210	IF A(I%)<>-10 THEN I%=I%+1% :
	GOTO 200   ! "-10" IS TERMINATOR SENT BY THE 8/E
213	IF I%=7% THEN 230
	!
	!
	!
	! CHECK FOR PEAKS WITH NEG AREA,RET TIME, OR HEIGHT
	!
	!
215	FOR L%=7% TO I%-5% STEP 5% :
	FOR M%=0% TO 2% :
	IF A(L%+M%)<0 THEN A(N%)=-25 FOR N%=L%-1% TO L%+3% :
	O%=1% :
	GOTO 220
217	NEXT M%
220	NEXT L% :
	IF O%=0% THEN 230 ELSE
	N%=6% :
	FOR L%=6% TO I% :
	IF A(L%)=-25 THEN 225 ELSE
	A(N%)=A(L%) :
	N%=N%+1%
225	NEXT L% :
	I%=N%-1%
230	E$=D$+"[10,"+NUM$(A(0))+"]PAMNEW"
240	OPEN E$ FOR INPUT AS FILE 2% :
	IF 4% AND ASCII(RIGHT(SYS(CHR$(6)+CHR$(-8)+CHR$(2)),4%)) THEN 330
	! CAN WE WRITE ON THE FILE?  IF NOT STICK IT IN THE BCK FILE
290	IF R1%(0)=200% OR P1%(0)+I%>15000% THEN 330
295	R1%(0)=R1%(0)+1% :
	R1%(R1%(0)),K%=P1%(0)
300	P1%(0)=K%+I%+1% :
	B(K%+J%)=A(J%) FOR J%=0% TO I% :
	CLOSE 2% :
	I%=0% :
	GOTO 200
330	CLOSE 2% :
	E$=D$+"[1,2]PAMNEW" :
	GOTO 240   !STICK IT IN THE BCK FILE
335	ON ERROR GOTO 350 :
	GOTO 330
340	IF ERR=21% THEN D$="DK0:" :
	RESUME 230
342	IF ERR=8% THEN E$=CHR$(0)+CHR$(12)+CHR$(13)+
	"NEED 8/E TURNED ON TO PROCEED!!!"+CHR$(12)+CHR$(13) :
	E$=SYS(CHR$(6)+CHR$(-5)+E$) :
	SLEEP 10% :
	RESUME 145	! KB2: CAN'T BE OPEN
345	IF ERR=52% THEN RESUME ELSE IF ERR=5% THEN
	RESUME 335
	!
	!
	! SET UP ERROR MESSAGE FOR KB0: AND RESTART PAM12
	!
	!
350	E$=CHR$(0)+CHR$(12)+CHR$(13)+"PAM12:  "+SYS(CHR$(6)+CHR$(9)+CHR$(ERR))+
	" AT LINE"+NUM$(ERL)+"  "+TIME$(0)+CHR$(12)+CHR$(13) :
	E$=SYS(CHR$(6)+CHR$(-5)+E$) :
	SLEEP 4% :
	CHAIN "PAM12"130 :
	END